Some tools to play with GnuPG’s smartcard daemon and OpenPGP smartcards.
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 

73 lines
2.3 KiB

dnl Configure template for the scdrand package
AC_INIT([scdtools], [0.3.4],
[dgouttegattat@incenp.org])
AC_CONFIG_SRCDIR([configure.ac])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_LIBOBJ_DIR([lib])
AC_USE_SYSTEM_EXTENSIONS
AM_INIT_AUTOMAKE([foreign])
dnl Check for development tools
AC_PROG_CC
AC_PROG_RANLIB
AC_PROG_INSTALL
dnl Check for some non-ubiquitous
ICP_CHECK_NOTCH_FUNCS
dnl Check for Assuan and libgpg-error
dnl Check for GnuPG libraries
AM_PATH_LIBGCRYPT([1.6.0],
[CFLAGS="$CFLAGS $LIBGCRYPT_CFLAGS"
LIBS="$LIBS $LIBGCRYPT_LIBS"],
[AC_MSG_ERROR([libgcrypt not found])])
AM_PATH_LIBASSUAN([2.1.0],
[CFLAGS="$CFLAGS $LIBASSUAN_CFLAGS"
LIBS="$LIBS $LIBASSUAN_LIBS"],
[AC_MSG_ERROR([libassuan not found])])
AM_PATH_GPG_ERROR([1.11],
[CFLAGS="$CFLAGS $GPG_ERROR_CFLAGS"
LIBS="$LIBS $GPG_ERROR_LIBS"],
[AC_MSG_ERROR([libgpg-error not found])])
dnl Path to gpg-connect-agent
AC_ARG_WITH([gpg-connect-agent],
[AS_HELP_STRING([--with-gpg-connect-agent],
[path to gpg-connect-agent @<:@default=/usr/bin/gpg-connect-agent@:>@])],
[gpg_connect_agent=$with_gpg_connect_agent],
[gpg_connect_agent=/usr/bin/gpg-connect-agent])
AC_DEFINE_UNQUOTED([GPG_CONNECT_AGENT_PATH], ["$gpg_connect_agent"],
[Path to gpg-connect-agent binary.])
dnl Default private DO for scdtotp
AC_ARG_WITH([default-do],
[AS_HELP_STRING([--with-default-do=N],
[Specify default private DO for scdtotp @<:@default=3@:>@])])
case $with_default_do in
1|2|3|4) ;;
*) with_default_do=3;;
esac
AC_DEFINE_UNQUOTED([DEFAULT_PRIVATE_DO], [$with_default_do],
[Default private DO for scdtotp.])
AC_SUBST([DEFAULT_PRIVATE_DO], [$with_default_do])
AC_SUBST([BUILD_DATE], [`date +%Y-%m-%d`])
dnl Output files
AC_CONFIG_FILES([Makefile lib/Makefile src/Makefile
man/Makefile man/scdrand.1 man/scdtotp.1])
AC_OUTPUT
dnl Summary
echo "
${PACKAGE_NAME} version ${PACKAGE_VERSION}
Configuration complete
Prefix: '${prefix}'
Compiler: '${CC} ${CFLAGS} ${CPPFLAGS}'
gpg-connect-agent: '${gpg_connect_agent}'
"