User limits utility.
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 

59 lines
1.7 KiB

dnl Configure template for the ulimits package
AC_INIT([User limits utility], [0.3.3],
[dgouttegattat@incenp.org], [ulimits])
AC_CONFIG_SRCDIR([configure.ac])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_LIBOBJ_DIR([lib])
AC_USE_SYSTEM_EXTENSIONS
AM_INIT_AUTOMAKE([foreign])
dnl Check for development tools
AC_PROG_CC
AC_PROG_RANLIB
AC_PROG_INSTALL
dnl Check for some non-ubiquitous functions
ICP_CHECK_NOTCH_FUNCS
dnl Check for Linux-specific prlimit function
AC_CHECK_FUNCS([prlimit])
dnl Check location of ps(1)
AC_PATH_PROG([PS_PATH], [ps])
AC_DEFINE_UNQUOTED([PS_PATH], ["$ac_cv_path_PS_PATH"], [Absolute path to ps(1).])
dnl Location of limits file
AC_ARG_WITH([limits-file],
[AS_HELP_STRING([--with-limits-file],
[path to the limits file @<:@default=/etc/limits@:>@])],
[limits_file=$with_limits_file],
[limits_file=/etc/limits])
AC_SUBST([LIMITS_FILE], ["$limits_file"])
dnl Should we merge all limits strings matching a given user?
dnl That's not the expected behavior, but maybe some people
dnl need that.
AC_ARG_ENABLE([merged-limits],
[AS_HELP_STRING([--enable-merged-limits],
[merge all limits strings matching the user])])
AS_IF([test "x$enable_merged_limits" = xyes],
[AC_DEFINE([ENABLE_MERGED_LIMITS], [1],
[Define whether limits strings should be merged])])
dnl Output files
AC_CONFIG_FILES([Makefile lib/Makefile src/Makefile
man/Makefile man/ulimits.1])
AC_OUTPUT
dnl Summary
echo "
${PACKAGE_NAME} version ${PACKAGE_VERSION}
Configuration complete
Prefix: '${prefix}'
Compiler: '${CC} ${CFLAGS} ${CPPFLAGS}'
"