KORG microX utility.
You can not select more than 25 topics Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
 
 
 

64 lines
1.9 KiB

dnl Configure template for the kmxtool package
AC_INIT([KORG microX utility], [0.1.0],
[dgouttegattat@incenp.org], [kmxtool])
AC_CONFIG_SRCDIR([configure.ac])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_LIBOBJ_DIR([lib])
AC_USE_SYSTEM_EXTENSIONS
AM_INIT_AUTOMAKE([foreign])
dnl Check for development tools
AC_PROG_CC
AC_PROG_RANLIB
AC_PROG_INSTALL
dnl Check for some non-ubiquitous functions
ICP_CHECK_NOTCH_FUNCS
dnl Choice of MIDI backend
midi_backend=
midi_default_port=
AC_ARG_WITH([alsa],
[AS_HELP_STRING([--with-alsa],
[use ALSA MIDI backend])],
[AS_IF([test "x$with_alsa" = xyes], [midi_backend=alsa])])
AC_ARG_WITH([oss],
[AS_HELP_STRING([--with-oss],
[use OSS MIDI backend])],
[AS_IF([test "x$with_oss" = xyes], [midi_backend=oss])])
dnl Check for selected backend
AS_CASE(["x$midi_backend"],
[xalsa],
[AM_PATH_ALSA([1.0.0],
[AC_DEFINE([USE_ALSA_MIDI_API], [1],
[Define wether to use the ALSA MIDI API.])
midi_default_port="hw:1,0,0"])],
[xoss],
[AC_DEFINE([USE_OSS_MIDI_API], [1],
[Define whether to use the OSS MIDI API.])
midi_default_port="/dev/midi00"],
[AC_MSG_ERROR([No MIDI backend selected.])])
AC_DEFINE_UNQUOTED([DEFAULT_MIDI_PORT], ["$midi_default_port"],
[Default MIDI port to use.])
AC_SUBST([DEFAULT_MIDI_PORT], [$midi_default_port])
dnl Output files
AC_CONFIG_FILES([Makefile lib/Makefile src/Makefile
man/Makefile man/asysex.1 man/kmxtool.1])
AC_OUTPUT
dnl Summary
echo "
${PACKAGE_NAME} version ${PACKAGE_VERSION}
Configuration complete
Prefix: '${prefix}'
Compiler: '${CC} ${CFLAGS} ${CPPFLAGS}'
MIDI backend: '${midi_backend}'
"