dnl Configure template for the fmail package

AC_INIT([fmail], [0.1],
        [dgouttegattat@incenp.org])
AC_CONFIG_SRCDIR([configure.ac])
AC_CONFIG_MACRO_DIR([m4])
AC_CONFIG_AUX_DIR([config])
AC_CONFIG_HEADERS([config.h])
AC_CONFIG_LIBOBJ_DIR([lib])
AC_USE_SYSTEM_EXTENSIONS
AM_INIT_AUTOMAKE([foreign])

dnl Check for development tools
AC_PROG_CC
AC_PROG_RANLIB
AC_PROG_INSTALL

dnl Check for some non-ubiquitous functions
ICP_CHECK_NOTCH_FUNCS

dnl Check for GPGME
AM_PATH_GPGME([],
              [CFLAGS="$CFLAGS $GPGME_CFLAGS"
               LIBS="$LIBS $GPGME_LIBS"],
              [AC_MSG_ERROR([libgpgme not found])])

dnl Check for libmagic
AC_CHECK_HEADERS([magic.h], [],
                 [AC_MSG_ERROR([magic.h header not found])])
AC_SEARCH_LIBS([magic_open], [magic], [],
               [AC_MSG_ERROR([libmagic not found])])

dnl Output files
AC_CONFIG_FILES([Makefile lib/Makefile src/Makefile
                 man/Makefile man/fmail.1])
AC_OUTPUT

dnl Summary
echo "

${PACKAGE_NAME} version ${PACKAGE_VERSION}
Configuration complete

Prefix:             '${prefix}'
Compiler:           '${CC} ${CFLAGS} ${CPPFLAGS}'

"